SuperTuxKart 1.5 upstream source (from official release tarball)

data/shaders/sunlight.frag

@@ -0,0 +1,38 @@
+uniform sampler2D ntex;
+uniform sampler2D dtex;
+
+uniform vec3 sundirection;
+uniform vec3 sun_color;
+
+#ifdef GL_ES
+layout (location = 0) out vec4 Diff;
+layout (location = 1) out vec4 Spec;
+#else
+out vec4 Diff;
+out vec4 Spec;
+#endif
+
+#stk_include "utils/decodeNormal.frag"
+#stk_include "utils/SpecularBRDF.frag"
+#stk_include "utils/DiffuseBRDF.frag"
+#stk_include "utils/getPosFromUVDepth.frag"
+#stk_include "utils/SunMRP.frag"
+
+void main() {
+    vec2 uv = gl_FragCoord.xy / u_screen;
+    float z = texture(dtex, uv).x;
+    vec4 xpos = getPosFromUVDepth(vec3(uv, z), u_inverse_projection_matrix);
+
+    vec3 norm = (u_view_matrix * vec4(DecodeNormal(texture(ntex, uv).xy), 0)).xyz;
+    float roughness = texture(ntex, uv).z;
+    vec3 eyedir = -normalize(xpos.xyz);
+
+    vec3 Lightdir = SunMRP(norm, eyedir);
+    float NdotL = clamp(dot(norm, Lightdir), 0., 1.);
+
+    vec3 Specular = SpecularBRDF(norm, eyedir, Lightdir, vec3(1.), roughness);
+    vec3 Diffuse = DiffuseBRDF(norm, eyedir, Lightdir, vec3(1.), roughness);
+
+    Diff = vec4(NdotL * Diffuse * sun_color, 1.);
+    Spec = vec4(NdotL * Specular * sun_color, 1.);
+}